【Hugo×AWS】独自ドメインを設定する（Route53+ACM）

【変更前】
https://dxxxxx.cloudfront.net/

【変更後】
https://example.com/  ← 独自ドメインでアクセス可能に

cd hugo-s3-demo-infra/prod
terraform output

cloudfront_distribution_id = "E2XXXXXXXXXX"
cloudfront_domain_name = "dxxxxx.cloudfront.net"

terraform {
  required_version = ">= 1.0"
  required_providers {
    aws = {
      source  = "hashicorp/aws"
      version = "~> 5.0"
    }
  }
}

# デフォルトプロバイダー（東京リージョン）
provider "aws" {
  region = "ap-northeast-1"

  default_tags {
    tags = {
      Project   = var.project_name
      ManagedBy = "terraform"
    }
  }
}

# us-east-1プロバイダー（ACM証明書用）
provider "aws" {
  alias  = "us_east_1"
  region = "us-east-1"

  default_tags {
    tags = {
      Project   = var.project_name
      ManagedBy = "terraform"
    }
  }
}

# ===========================================
# ACM証明書（us-east-1で作成）
# ===========================================
resource "aws_acm_certificate" "main" {
  provider = aws.us_east_1  # us-east-1で作成

  domain_name               = var.domain_name
  subject_alternative_names = ["*.${var.domain_name}"]
  validation_method         = "DNS"

  lifecycle {
    create_before_destroy = true
  }

  tags = {
    Name = "${var.project_name}-certificate"
  }
}

# ===========================================
# DNS検証用レコード
# ===========================================
resource "aws_route53_record" "acm_validation" {
  for_each = {
    for dvo in aws_acm_certificate.main.domain_validation_options : dvo.domain_name => {
      name   = dvo.resource_record_name
      record = dvo.resource_record_value
      type   = dvo.resource_record_type
    }
  }

  zone_id = data.aws_route53_zone.main.zone_id
  name    = each.value.name
  type    = each.value.type
  records = [each.value.record]
  ttl     = 60

  allow_overwrite = true
}

# ===========================================
# 証明書の検証完了を待機
# ===========================================
resource "aws_acm_certificate_validation" "main" {
  provider = aws.us_east_1

  certificate_arn         = aws_acm_certificate.main.arn
  validation_record_fqdns = [for record in aws_route53_record.acm_validation : record.fqdn]
}

resource "aws_acm_certificate" "main" {
  provider = aws.us_east_1  # 重要: us-east-1で作成

  domain_name               = var.domain_name          # example.com
  subject_alternative_names = ["*.${var.domain_name}"] # *.example.com（ワイルドカード）
  validation_method         = "DNS"                    # DNS検証
}

resource "aws_route53_record" "acm_validation" {
  for_each = {
    for dvo in aws_acm_certificate.main.domain_validation_options : dvo.domain_name => { ... }
  }
  # ...
}

resource "aws_acm_certificate_validation" "main" {
  certificate_arn         = aws_acm_certificate.main.arn
  validation_record_fqdns = [for record in aws_route53_record.acm_validation : record.fqdn]
}

variable "domain_name" {
  description = "Domain name for the website"
  type        = string
}

domain_name = "example.com"  # 購入したドメイン名に置き換え

# ===========================================
# ホストゾーンの参照（ドメイン購入時に自動作成済み）
# ===========================================
data "aws_route53_zone" "main" {
  name         = var.domain_name
  private_zone = false
}

# ===========================================
# Aliasレコード（CloudFrontへのルーティング）
# ===========================================
resource "aws_route53_record" "main" {
  zone_id = data.aws_route53_zone.main.zone_id
  name    = var.domain_name
  type    = "A"

  alias {
    name                   = aws_cloudfront_distribution.main.domain_name
    zone_id                = aws_cloudfront_distribution.main.hosted_zone_id
    evaluate_target_health = false
  }
}

# wwwサブドメイン用（任意）
resource "aws_route53_record" "www" {
  zone_id = data.aws_route53_zone.main.zone_id
  name    = "www.${var.domain_name}"
  type    = "A"

  alias {
    name                   = aws_cloudfront_distribution.main.domain_name
    zone_id                = aws_cloudfront_distribution.main.hosted_zone_id
    evaluate_target_health = false
  }
}

# ===========================================
# Outputs
# ===========================================
output "website_url" {
  value = "https://${var.domain_name}"
}

data "aws_route53_zone" "main" {
  name         = var.domain_name
  private_zone = false
}

resource "aws_route53_record" "main" {
  type = "A"

  alias {
    name                   = aws_cloudfront_distribution.main.domain_name
    zone_id                = aws_cloudfront_distribution.main.hosted_zone_id
    evaluate_target_health = false
  }
}

resource "aws_cloudfront_distribution" "main" {
  # ...既存の設定...

  # カスタムドメインを追加
  aliases = [var.domain_name, "www.${var.domain_name}"]

  # viewer_certificate を修正
  viewer_certificate {
    acm_certificate_arn      = aws_acm_certificate.main.arn
    ssl_support_method       = "sni-only"
    minimum_protocol_version = "TLSv1.2_2021"
  }

  # 証明書の検証完了を待ってから作成
  depends_on = [aws_acm_certificate_validation.main]

  # ...既存の設定...
}

aliases = [var.domain_name, "www.${var.domain_name}"]

viewer_certificate {
  acm_certificate_arn      = aws_acm_certificate.main.arn
  ssl_support_method       = "sni-only"
  minimum_protocol_version = "TLSv1.2_2021"
}

depends_on = [aws_acm_certificate_validation.main]

baseURL = 'https://example.com/'
languageCode = 'en-us'
title = 'My Tech Blog'
theme = 'ananke'

terraform plan
terraform apply